#!/usr/bin/perl -w
# md5sums -- lintian collection script

# Copyright (C) 1998 Richard Braakman
# 
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
# 
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
# 
# You should have received a copy of the GNU General Public License
# along with this program.  If not, you can find it on the World Wide
# Web at http://www.gnu.org/copyleft/gpl.html, or write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
# MA 02110-1301, USA.

use strict;
use warnings;

use FileHandle;
use lib "$ENV{'LINTIAN_ROOT'}/lib";
use Lintian::Collect;
use Lintian::Command qw(spawn reap);
use Lintian::Util qw(fail);

($#ARGV == 2) or fail 'syntax: md5sums <pkg> <type> <dir>';

my ($pkg, $type, $dir) = @ARGV;
my $info = Lintian::Collect->new ($pkg, $type, $dir);

if ( -e "$dir/md5sums" ) {
    unlink "$dir/md5sums" or fail "unlink md5sums: $!";
}

chdir ("$dir/unpacked")
    or fail("cannot chdir to unpacked directory: $!");

my %opts = ( pipe_in => FileHandle->new,
             out => "$dir/md5sums",
             fail => 'error' );
spawn(\%opts, ['xargs', '-0r', 'md5sum'] );
$opts{pipe_in}->blocking(1);

foreach my $file ($info->sorted_index) {
    next unless $file;
    next unless $info->index->{$file}->{type} =~ m/^[-h]/;
    printf {$opts{pipe_in}} "%s\0", $file;
}

close $opts{pipe_in};
reap(\%opts);

# Local Variables:
# indent-tabs-mode: nil
# cperl-indent-level: 4
# End:
# vim: syntax=perl sw=4 sts=4 sr et
